[Bug 1583791] [NEW] xenial kturtle file-browser doesn't find .turtle-files
Stephen Hamer
1583791 at bugs.launchpad.net
Thu May 19 20:59:48 UTC 2016
Public bug reported:
Running 32-bit Ubuntu 16.04 from an eternal USB hard-drive attached to
an N110 netbook.
Here's the problem: the file-browser of the standard version of kturtle
from the Xenial repos (version 0.8.1 beta) doesn't find "*.turtle"-files
(which it somewhat oddly lists as ".*turtle"-files). To find your
"*.turtle"-files, you have to select "All files" from the file-browser
drop-down menu.
Also:
1. If you try to open a turtle file from a terminal with:
[code]
kturtle -i /path/file.turtle
[/code]
you get an error-message:
"Malformed URL /path/file.turtle."
Finally:
2. The ap will save a new "*.turtle"-file, but doesn't seem to register
that it has saved it. If you try to open a new turtle-script after
saving a script as a turtle-file, the ap notifies you that you are going
to lose the changes that you've just saved.
If you want to play around with kturtle, try pasting the code below into
the edit window. See if you can find it after you've saved it:
[code]
#script to draw a sequence of recursively-constructed branching pattern
#n determines the size of the pattern, p its position in the sequence
#take n = power of 2=<512, 1=<p=<7
#The script, below, consists of just one 'routine', activated with the command "tree n, p", where 'n' and 'p' are parameters as previously described.
#This basic 'tree'-routine contains within it a number of 'internal' sub-routines, also defined with the learn-command, and shown offset:
#"t1" draws the first pattern in the sequence
#"tp" draws the pth pattern (p>=2) as a line segment of length n/2 surmounted by a "crown" of half-scale (p-1)th patterns
#a 'branch' sub-routine is also included to improve the symmetry of the final design
learn tree $n, $p
{
reset
cs 1200, 1200
center
spritehide
#basic canvas preparation commands
go 0, 0 pw 10 pc 255, 255, 255 repeat 4 {tr 90 fw 1200} pw 1 pc 0, 0, 0 go 600, 600
#paints out the black-line border of the canvas
$c=0
if $p==1 {$t=0} else {$t=255/($p-1)}
#parameters used to define the colours of the branches in each pattern. t (depends on p) is a "tint-increment" which deepens the redness o the branches drawn at each iteration
$w=2^($p-1)
#parameter determining the "width" of the branches in each pattern
learn t1 $n, $c, $t, $w
{
#sub-routine to draw the first (p=1) figure
pc 0+($c*$t), 255-($c*$t), 0
pw $w
fw $n
pu bw $n pd
}
learn tp $n, $p, $c, $t, $w
{
#sub-routine to draw the pth figure for p>=2
$q=0
pc 0+($c*$t), 255-($c*$t), 0
pw $w
fw $n
tl 75
while $q<6 {if $p>2 {tp $n/2, $p-1, $c+1, $t, $w/2} else {t1 $n/2, $c+1, $t, $w/2} tr ((0-1)^$q)*(150-30*$q) $q=$q+1}
tl 15
pu bw $n pd
}
learn tallp $n, $p, $c, $t, $w
{
#sub-routine to draw the pth figure for p>=1
if $p==1 {t1 $n, $c, $t, $w} else {tp $n, $p, $c, $t, $w}
}
learn branch $n, $p, $c, $t, $w
{
#sub-routine to re-draw one of the "branches" on the final figure (improves the symmetry of the final figure)
tl 15 pu fw $n/2 pd
tr 75
if $p>2 {tp $n/4, $p-2, $c+2, $t, $w/4}
tl 75
pu bw $n/2 pd tr 15
}
pu
bw $n
pd
#positions the drawing-point at the bottom of the screen preparatory to drawing the tree
tallp $n, $p, $c, $t, $w
#draws the tree
pu
fw $n
pd
#moves the drawing-point back to the screen-centre
branch $n, $p, $c, $t, $w
#re-draws one of the branches to improve the symmetry of the final design
pc 0, 0, 0
pw 1
#returns the pen to its initial state
}
tree 512, 6
[/code]
Hope you grey-beards can fix this bug, ut if you can't, you at least got
to see a pretty picture.
** Affects: kturtle (Ubuntu)
Importance: Undecided
Status: New
--
You received this bug notification because you are a member of Kubuntu
Bugs, which is subscribed to kturtle in Ubuntu.
https://bugs.launchpad.net/bugs/1583791
Title:
xenial kturtle file-browser doesn't find .turtle-files
To manage notifications about this bug go to:
https://bugs.launchpad.net/ubuntu/+source/kturtle/+bug/1583791/+subscriptions
More information about the kubuntu-bugs
mailing list